Atom+RDFa 1.1

Table of Contents

• 1. Introduction
• 2. Conformance Requirements
  • 2.1 Conformance
  • 2.2 Document Conformance
  • 2.3 User Agent Conformance
• 3. Additional RDFa Processing Rules
• 4. Default Profile
• 5. Native Atom Semantics
• 6. Relax NG Compact Schema
• A. Acknowledgements
• B. References
  • B.1 Normative references
  • B.2 Informative references

2. Conformance Requirements

3. Additional RDFa Processing Rules

Documents conforming to the rules in this specification are processed according to RDFa Core 1.1 [RDFA-CORE] with the following extensions:

• The default vocabulary URI is initially undefined.
• The default collection of terms is defined via an RDFa Profile document detailed in section 4. Default Profile.
• The base is set using the xml:base attribute as defined in XML Base [XMLBASE].
• The current language is set using the @xml:lang [XML10-4e] attribute
• In section 7.5, processing step 6, if no URI is provided by a resource attribute (e.g., about, href, resource, or src), then first check to see if the element is an <entry> element. If it is, then behave as if there is a typeof present with the empty string as its attribute value, and process it according to the rule for typeof.
• In section 7.5, processing step 7, if no URI is provided by a resource attribute (e.g., about, href, resource, or src), then first check to see if the element is an <entry> element. If it is, then behave as if there is a typeof present with the empty string as its attribute value, and process it according to the rule for typeof.

@@TODO - maybe mention the <?profile ?> processing instruction from DataRSS?

4. Default Profile

RDFa Working Group has decided to have a single default profile for all host languages. That means that Atom+RDFa needs to adopt that profile. But is it also allowed to specify its own default profile that will be used in addition to the RDFa Core default profile? Atom+RDFa needs to be able to do so for compatibility with native Atom semantics.

The default profile is obtained by processing the XML version [REL-REG] of the IETF Link Registry [RFC5988] with the following XSL Transformation:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:reg="http://www.iana.org/assignments"
  xmlns:dc="http://purl.org/dc/terms/"
  xmlns:rel="http://www.iana.org/assignments/relation/"
  xmlns:rdfs="http://www.w3.org/2000/01/rdf-schema#"
  xmlns:xsd="http://www.w3.org/2001/XMLSchema#"
  xmlns:rdfa="http://www.w3.org/ns/rdfa#">
  
  <xsl:output method="xml" indent="yes"/> 
 
  <xsl:template match="//reg:registry[@id]">
    <reg:registry id="{@id}" about="#{@id}">
      <xsl:apply-templates select="reg:title"/>
      <xsl:apply-templates select="reg:updated"/>
      <xsl:apply-templates select="reg:registry"/>
      <xsl:apply-templates select="reg:record"/>
    </reg:registry>
  </xsl:template> 

  <xsl:template match="reg:title">
    <reg:title property="dc:title" xml:lang="en">
      <xsl:value-of select="."/>
    </reg:title>
  </xsl:template>

  <xsl:template match="reg:updated">
    <reg:updated property="dc:modified" datatype="xsd:date">
      <xsl:value-of select="."/>
    </reg:updated>
  </xsl:template>
  
  <xsl:template match="reg:record">
    <reg:record typeof="rdfa:TermMapping"
      property="rdfa:uri"
      content="http://www.iana.org/assignments/relation/{reg:value}">
      <xsl:apply-templates select="reg:value"/>
      <xsl:apply-templates select="reg:description"/>
      <xsl:apply-templates select="reg:xref[@type='uri']"/>
    </reg:record>
  </xsl:template>

  <xsl:template match="reg:value">
    <reg:value property="rdfa:term">
      <xsl:value-of select="."/>
    </reg:value>
  </xsl:template>

  <xsl:template match="reg:description">
    <reg:description
      about="[rel:{ancestor::reg:record/reg:value}]"
      property="rdfs:comment"
      xml:lang="en">
      <xsl:value-of select="."/>
    </reg:description>
  </xsl:template>

  <xsl:template match="reg:xref[@type='uri']">
    <reg:xref
      about="[rel:{ancestor::reg:record/reg:value}]"
      rel="rdfs:seeAlso"
      resource="{./@data}">
      <xsl:value-of select="."/>
    </reg:xref>
  </xsl:template>

</xsl:stylesheet>

Implementations are not required to implement XSLT. Other techniques that result in an equivalent profile are allowed.