diff -urN Moo-1.000003/lib/Moo/Role.pm Moo-dev/lib/Moo/Role.pm
--- Moo-1.000003/lib/Moo/Role.pm	2012-10-03 16:26:16.275917561 +0100
+++ Moo-dev/lib/Moo/Role.pm	2012-10-03 17:03:32.956916747 +0100
@@ -25,13 +25,17 @@
   # get symbol table reference
   my $stash = do { no strict 'refs'; \%{"${target}::"} };
   _install_tracked $target => has => sub {
-    my ($name, %spec) = @_;
-    ($INFO{$target}{accessor_maker} ||= do {
-      require Method::Generate::Accessor;
-      Method::Generate::Accessor->new
-    })->generate_method($target, $name, \%spec);
-    push @{$INFO{$target}{attributes}||=[]}, $name, \%spec;
-    $me->_maybe_reset_handlemoose($target);
+    my ($name_proto, %spec) = @_;
+    my $name_isref = ref $name_proto eq 'ARRAY';
+    foreach my $name ($name_isref ? @$name_proto : $name_proto) {
+      my $spec_ref = $name_isref ? +{%spec} : \%spec;
+      ($INFO{$target}{accessor_maker} ||= do {
+        require Method::Generate::Accessor;
+        Method::Generate::Accessor->new
+      })->generate_method($target, $name, $spec_ref);
+      push @{$INFO{$target}{attributes}||=[]}, $name, $spec_ref;
+      $me->_maybe_reset_handlemoose($target);
+    }
   };
   # install before/after/around subs
   foreach my $type (qw(before after around)) {
diff -urN Moo-1.000003/lib/Moo.pm Moo-dev/lib/Moo.pm
--- Moo-1.000003/lib/Moo.pm	2012-10-03 16:26:16.277917676 +0100
+++ Moo-dev/lib/Moo.pm	2012-10-03 17:03:25.571663755 +0100
@@ -35,12 +35,18 @@
     $class->_maybe_reset_handlemoose($target);
   };
   _install_tracked $target => has => sub {
-    my ($name, %spec) = @_;
-    $class->_constructor_maker_for($target)
-          ->register_attribute_specs($name, \%spec);
-    $class->_accessor_maker_for($target)
-          ->generate_method($target, $name, \%spec);
-    $class->_maybe_reset_handlemoose($target);
+    my ($name_proto, %spec) = @_;
+    my $name_isref = ref $name_proto eq 'ARRAY';
+    foreach my $name ($name_isref ? @$name_proto : $name_proto) {
+      # Note that when $name_proto is an arrayref, each attribute
+      # needs a separate \%specs hashref
+      my $spec_ref = $name_isref ? +{%spec} : \%spec;
+      $class->_constructor_maker_for($target)
+            ->register_attribute_specs($name, $spec_ref);
+      $class->_accessor_maker_for($target)
+            ->generate_method($target, $name, $spec_ref);
+      $class->_maybe_reset_handlemoose($target);
+    }
     return;
   };
   foreach my $type (qw(before after around)) {
diff -urN Moo-1.000003/t/has-array.t Moo-dev/t/has-array.t
--- Moo-1.000003/t/has-array.t	1970-01-01 01:00:00.000000000 +0100
+++ Moo-dev/t/has-array.t	2012-10-03 16:42:32.489923252 +0100
@@ -0,0 +1,30 @@
+use Test::More tests => 4;
+
+ok(eval {
+  package Local::Test::Role1;
+  use Moo::Role;
+  has [qw/ attr1 attr2 /] => (is => 'ro');
+  1;
+}, 'has \@attrs works in roles')
+  or diag "EVAL FAILED: $@";
+
+ok eval {
+  package Local::Test::Class1;
+  use Moo;
+  with 'Local::Test::Role1';
+  has [qw/ attr3 attr4 /] => (is => 'ro');
+  1;
+}, 'has \@attrs works in classes'
+  or diag "EVAL FAILED: $@";
+
+my $obj = new_ok 'Local::Test::Class1' => [
+  attr1  => 1,
+  attr2  => 2,
+  attr3  => 3,
+  attr4  => 4,
+];
+
+can_ok(
+  $obj,
+  qw( attr1 attr2 attr3 attr4 ),
+);